sublime_text右键菜单

sublime_text安装目录根路径执行

@ECHO OFF & PUSHD %~DP0 & TITLE
>NUL 2>&1 REG.exe query "HKU\S-1-5-19" || (
    ECHO SET UAC = CreateObject^("Shell.Application"^) > "%TEMP%\Getadmin.vbs"
    ECHO UAC.ShellExecute "%~f0", "%1", "", "runas", 1 >> "%TEMP%\Getadmin.vbs"
    "%TEMP%\Getadmin.vbs"
    DEL /f /q "%TEMP%\Getadmin.vbs" 2>NUL
    Exit /b
)
SET /P ST=输入a添加右键菜单，输入d删除右键菜单：
if /I "%ST%"=="a" goto Add
if /I "%ST%"=="d" goto Remove
:Add
reg add "HKEY_CLASSES_ROOT\*\shell\Sublime Text" /t REG_SZ /v "" /d "用 &Sublime Text 打开" /f
reg add "HKEY_CLASSES_ROOT\*\shell\Sublime Text" /t REG_EXPAND_SZ /v "Icon" /d "%~dp0sublime_text.exe" /f
reg add "HKEY_CLASSES_ROOT\*\shell\Sublime Text\command" /t REG_SZ /v "" /d "%~dp0sublime_text.exe \"%%1\"" /f
 
exit
:Remove
reg delete "HKEY_CLASSES_ROOT\*\shell\Sublime Text" /f
exit

java 环境变量配置

::添加环境变量JAVA_HOME
::echo off 表示在批处理文件执行过程中，只显示结果，而不显示执行的命令
@echo on
echo 添加Java环境变量
setx /M JAVA_HOME "C:\Program Files\Java\jdk1.8.0_171"
setx /M Path "%Path%;%%JAVA_HOME%%\bin;%%JAVA_HOME%%\jre\bin;"
setx /M CLASSPATH ".;%%JAVA_HOME%%\lib\dt.jar;%%JAVA_HOME%%\lib\tools.jar;"
::pause命令运行后会中断执行的语句。这个中断不是立即停止，只是暂停
::按下任意键之后就会继续执行下面的语句。
pause
::添加环境变量之后不会在本cmd窗口生效，所以%JAVA_HOME%没有值
::需要输入  %%JAVA_HOME%% 显示 %JAVA_HOME%

oracle 环境变量配置

@echo off
setx /m ORACLE_HOME D:\Programs\PLSQL\instantclient_11_2
setx /m TNS_ADMIN D:\Programs\PLSQL\instantclient_11_2
setx /m NLS_LANG AMERICAN_AMERICA.UTF8

pause

maven 本地仓库清理

@echo  off
set REPOSITORY_PATH=D:\Programs\Apache\apache-maven-3.6.0\repo
rem 正在搜索...
for /f "delims=" %%i in ('dir /b /s "%REPOSITORY_PATH%\*lastUpdated*"') do (
    del /s /q %%i
)
for /f "delims=" %%i in ('dir /b /s "%REPOSITORY_PATH%\_remote.reposiories"') do (
    del /s /q %%i
)
rem 搜索完毕
pause